User:Mnamihdk

SELECT ?library ?libraryLabel ?classLabel ?isil ?ndl_auth ?postcode
WHERE {
  ?library (wdt:P31/wdt:P279*) wd:Q7075.  # instance of any subclass of library
  ?library wdt:P17 wd:Q17.  # 国 == 日本
  MINUS {
      ?library wdt:P31 wd:Q28324850  # 分類 != 図書館システム
   }
  OPTIONAL {?library wdt:P31 ?class}  # 分類
  OPTIONAL {?library wdt:P791 ?isil}  # ISIL識別子
  OPTIONAL {?library wdt:P349 ?ndl_auth}  # 国立国会図書館典拠ID
  OPTIONAL {?library wdt:P281 ?postcode}  # 郵便番号
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
}

SELECT ?subclass ?subclassLabel ?count 
WHERE {
  {
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.  # instance of subclass
      ?subclass wdt:P279* wd:Q7075.  # any subclass of library
    }
    GROUP BY ?subclass
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)

SELECT ?subclass ?subclassLabel ?count 
WHERE {
  {
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.  # instance of subclass
      ?subclass wdt:P279* wd:Q7075.  # any subclass of library
      ?library wdt:P17 wd:Q17.  # 国 == 日本
    }
    GROUP BY ?subclass
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)

SELECT ?aggType ?subclassLabel ?count (?subclass AS ?subclassEntity) 
WHERE {
  {
    #　subclassのエンティティとsubclassごとの合計件数
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.
      ?subclass wdt:P279* wd:Q7075.
      ?library wdt:P17 wd:Q17.
    }
    GROUP BY ?subclass
  }
  UNION
  {
    #　subclassごとの合計のさらに合計（延べ件数＝複数のsubclassに分類されている場合はそれぞれを1件と数える＝件数に重複あり）
    SELECT ("延べ件数" AS ?aggType) (SUM(?count) AS ?count)
    WHERE {
      {
        SELECT (COUNT(DISTINCT ?library) AS ?count)  #　subclassごとの合計
        WHERE {
          ?library wdt:P31 ?subclass.
          ?subclass wdt:P279* wd:Q7075.
          ?library wdt:P17 wd:Q17.
        }
        GROUP BY ?subclass
      }
    }
  }
  UNION
  {
    #　項目のユニーク件数（複数のsubclassに分類されている場合でもIDが同じなら合わせて1件＝件数に重複なし）
    SELECT ("ユニーク件数" AS ?aggType) (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31/wdt:P279* wd:Q7075.
      ?library wdt:P17 wd:Q17.
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)

SELECT ?subclass ?subclassLabel ?count 
WHERE {
  {
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      # 私立図書館及びその下位クラスに分類されている項目で国が日本であるもの
      ?library wdt:P31 ?subclass.
      ?subclass wdt:P279* wd:Q7631964.
      ?library wdt:P17 wd:Q17.
    }
    GROUP BY ?subclass
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)

SELECT ?__ ?__Label ?loc ?jawp WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en". }
  ?__ (wdt:P31/wdt:P279*) wd:Q7075;
        wdt:P17 wd:Q17.
  OPTIONAL {?__ wdt:P791 ?isil;}
  FILTER (!BOUND(?isil)) 
  OPTIONAL { ?__ rdfs:label ?l. FILTER (lang(?l) = 'ja') }
  FILTER (BOUND(?l))
  FILTER (CONTAINS(?l, "立"@ja))
}
LIMIT 1000

SELECT DISTINCT (?library AS ?entity) ?label ?isil ?ndl_auth ?postcode
WHERE {
  ?library wdt:P31/wdt:P279* wd:Q7075.
  ?library wdt:P17 wd:Q17.
  ?library rdfs:label ?label.
  OPTIONAL { ?library wdt:P791 ?isil. }
  OPTIONAL { ?library wdt:P349 ?ndl_auth. }
  OPTIONAL { ?library wdt:P281 ?postcode. }
  FILTER(LANG(?label) = "ja").
  FILTER(CONTAINS(?label, "文庫")).
}